1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
.section .shared
.global _isr_stubs
_isr_stubs:
.rept 256
.set _stub_start, .
cli
call _isr_stage2
.if . - _stub_start > 8
.error "isr stubs over maximum size"
.abort
.endif
.align 8
.endr
_isr_stage2:
// pushal order, without %esp
push %eax
push %ecx
push %edx
push %ebx
push %ebp
push %esi
push %edi
// convert the return address into the vector nr
mov 28(%esp), %eax
add $-_isr_stubs, %eax
shr $3, %eax
// disable paging, if present
mov %cr0, %ebx
push %ebx // push original cr0
and $0x7FFFFFFF, %ebx
mov %ebx, %cr0
mov %esp, %ebp
mov $_isr_big_stack, %esp
push %eax // push the vector nr
call isr_stage3
mov %ebp, %esp
pop %eax // restore old cr0
mov %eax, %cr0
// restore registers
pop %edi
pop %esi
pop %ebp
pop %ebx
pop %edx
pop %ecx
pop %eax
add $4, %esp // skip call's return address
iret
.align 8
// TODO overflow check
.skip 64 // seems to be enough
.global _isr_mini_stack
_isr_mini_stack:
|
